feat: add crafttweaker recipes

overrides/contentScripts/ae2.zs

@@ -0,0 +1,20 @@
+import mods.content.Item;
+
+Item.registerItem(
+    "Calculation Processor Assembly",
+    "calculation_processor_assembly",
+    "calculation_processor_assembly_item"
+);
+
+Item.registerItem(
+    "Engineering Processor Assembly",
+    "engineering_processor_assembly",
+    "engineering_processor_assembly_item"
+);
+
+Item.registerItem(
+    "Logic Processor Assembly",
+    "logic_processor_assembly",
+    "logic_processor_assembly_item"
+);
+

overrides/resources/contenttweaker/lang/en_US.lang

@@ -0,0 +1,3 @@
+item.calculation_processor_assembly.name=Calculation Processor Assembly
+item.engineering_processor_assembly.name=Engineering Processor Assembly
+item.logic_processor_assembly.name=Logic Processor Assembly

overrides/scripts/ae2.zs

@@ -0,0 +1,63 @@
+import minetweaker.item.IItemStack;
+import minetweaker.item.IIngredient;
+
+val logicProcessor = <appliedenergistics2:item.ItemMultiMaterial:22>;
+val calculationProcessor = <appliedenergistics2:item.ItemMultiMaterial:23>;
+val engineeringProcessor = <appliedenergistics2:item.ItemMultiMaterial:24>;
+
+function processorAssemblyRecipe(
+    processorAssembly as IItemStack,
+    middle as IIngredient
+) {
+    // certus knife
+    recipes.addShaped(
+        processorAssembly,
+        [
+            [
+                null,
+                <appliedenergistics2:item.ToolCertusQuartzCuttingKnife>
+                    .anyDamage(),
+                null
+            ],
+            [<minecraft:redstone>, middle, <minecraft:redstone>],
+            [null, <ore:itemSilicon>, null]
+        ]
+    );
+
+    // quartz knife
+    recipes.addShaped(
+        processorAssembly,
+        [
+            [
+                null,
+                <appliedenergistics2:item.ToolNetherQuartzCuttingKnife>
+                    .anyDamage(),
+                null
+            ],
+            [<minecraft:redstone>, middle, <minecraft:redstone>],
+            [null, <ore:itemSilicon>, null]
+        ]
+    );
+}
+
+// processor assembly recipes
+processorAssemblyRecipe(
+    <contenttweaker:logic_processor_assembly>,
+    <ore:ingotGold>
+);
+processorAssemblyRecipe(
+    <contenttweaker:calculation_processor_assembly>,
+    <appliedenergistics2:item.ItemMultiMaterial:10>
+);
+processorAssemblyRecipe(
+    <contenttweaker:engineering_processor_assembly>,
+    <ore:gemDiamond>
+);
+
+// processor recipes
+furnace.addRecipe(logicProcessor, <contenttweaker:logic_processor_assembly>);
+furnace.addRecipe(calculationProcessor, <contenttweaker:calculation_processor_assembly>);
+furnace.addRecipe(engineeringProcessor, <contenttweaker:engineering_processor_assembly>);
+
+// remove inscriber
+recipes.remove(<appliedenergistics2:tile.BlockInscriber>);

overrides/scripts/ic2.zs

@@ -0,0 +1,39 @@
+val refinedIron = <IC2:itemIngot:3>;
+val copperCable = <IC2:itemCable:0>;
+
+// old-school refined iron
+furnace.addRecipe(refinedIron, <ore:ingotIron>);
+
+// refined iron circuits
+recipes.remove(<IC2:itemPartCircuit>);
+
+// horizontal
+recipes.addShaped(
+    <IC2:itemPartCircuit>,
+    [
+        [copperCable, copperCable, copperCable],
+        [<minecraft:redstone>, refinedIron, <minecraft:redstone>],
+        [copperCable, copperCable, copperCable]
+    ]
+);
+
+// vertical
+recipes.addShaped(
+    <IC2:itemPartCircuit>,
+    [
+        [copperCable, <minecraft:redstone>, copperCable],
+        [copperCable, refinedIron, copperCable],
+        [copperCable, <minecraft:redstone>, copperCable]
+    ]
+);
+
+// refined iron machine blocks
+recipes.remove(<IC2:blockMachine>);
+recipes.addShaped(
+    <IC2:blockMachine>,
+    [
+        [refinedIron, refinedIron, refinedIron],
+        [refinedIron, null, refinedIron],
+        [refinedIron, refinedIron, refinedIron],
+    ]
+);

overrides/scripts/mekanism.zs

@@ -0,0 +1,22 @@
+import minetweaker.item.IItemStack;
+import minetweaker.item.IIngredient;
+
+val universalCable = <Mekanism:PartTransmitter:0>;
+val mechanicalPipe = <Mekanism:PartTransmitter:4>;
+val pressurizedTube = <Mekanism:PartTransmitter:8>;
+val logisticalTransporter = <Mekanism:PartTransmitter:12>;
+val thermodynamicConductor = <Mekanism:PartTransmitter:18>;
+
+function pipeRecipe(pipe as IItemStack, middleItem as IIngredient) {
+    recipes.remove(pipe);
+    recipes.addShaped(
+        pipe,
+        [[<ore:ingotOsmium>, middleItem, <ore:ingotOsmium>]]
+    );
+}
+
+pipeRecipe(universalCable, <minecraft:redstone>);
+pipeRecipe(mechanicalPipe, <minecraft:bucket>);
+pipeRecipe(pressurizedTube, <ore:blockGlass>);
+pipeRecipe(logisticalTransporter, <ore:circuitBasic>);
+pipeRecipe(thermodynamicConductor, <ore:ingotCopper>);