buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "https://maven.minecraftforge.net/"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath ("com.anatawa12.forge:ForgeGradle:1.2-1.0.+") {
            changing = true
        }
    }
}

apply plugin: "forge"
apply plugin: "maven-publish"

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

version = "0.2.0"
group= "net.anvilcraft"
archivesBaseName = "pccompat"

minecraft {
    version = "1.7.10-10.13.4.1614-1.7.10"
    runDir = "run"
}

repositories {
    maven { url = "https://maven.tilera.xyz" }
    maven {
        url = "https://s3.tilera.xyz/cdn/minecraft/libs/"
        metadataSources { artifact() }
    }
    maven {
        name "central"
        url "https://nexus.covers1624.net/repository/maven-hosted/"
    }
}

// WARNING!!! DON'T CHANGE THE ORDER OF DEPENDENCIES!
// OTHER ORDERS MIGHT CAUSE CRASHES!
dependencies {
    implementation "appeng:appliedenergistics2:rv3-beta-21:dev"
    implementation "codechicken:CodeChickenCore:1.7.10-1.0.7.48:dev"
    implementation "codechicken:CodeChickenLib:1.7.10-1.1.3.141:dev"
    implementation "codechicken:NotEnoughItems:1.7.10-1.0.5.120:dev"
    implementation "codechicken:ForgeMultipart:1.7.10-1.2.0.347:dev"
    implementation "cofh:CoFHCore:[1.7.10]3.1.4-329:dev"
    implementation "com.eloraam.redpower:redpower:2.0pr10-dirty:deobf"
    implementation "com.hbm:HBM-NTM:1.0.27_X4627:deobf"
    implementation "covers1624:PowerConverters:1.7.10-2.11:deobf"
    implementation "universalelectricity:basiccomponents:2.0.1:deobf"
    implementation "universalelectricity:universalelectricity:5.2.2:deobf"
    implementation "mods:HEXCraft:1.7.10-0.13.2:deobf"
    implementation "mods:magneticraft:0.6.1:deobf"
    implementation "mods:ElectricalAge:1.20.3:deobf"
    implementation "net.industrial-craft:industrialcraft-2:2.2.827-experimental:dev"
    implementation "mods:Ultratech:1.7.10-0.9.6.1:deobf"
    implementation "mods:gregtech:5.09.31:dev"
    implementation "mods:Railcraft_1.7.10:9.12.2.0"
    implementation "mods:MrTJPCore:1.1.0.31:dev"
    implementation "mods:ForgeRelocation:0.0.1.4:dev"
    implementation "mods:ProjectRed:1.7.10-4.7.0pre8.92:dev"
    compileOnly "mods:DragonAPI:1.7.10-V32c:deobf"
    compileOnly "mods:RotaryCraft:1.7.10-V32c:deobf"
    compileOnly "mods:ElectriCraft:1.7.10-V32b:deobf"
}

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    filesMatching("mcmod.info") {
        expand "version":project.version, "mcversion":project.minecraft.version
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = "deobf"
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = "sources"
}

publishing {
    tasks.publish.dependsOn "build"
    publications {
        mavenJava(MavenPublication) {
            artifactId = project.archivesBaseName

            artifact deobfJar
            artifact sourcesJar
            artifact jar
        }
    }

    repositories {
        if (project.hasProperty("mvnURL")) {
                maven {
                    credentials {
                        username findProperty("mvnUsername")
                        password findProperty("mvnPassword")
                    }
                    url = findProperty("mvnURL")
                }
        }
        else {
                mavenLocal()
        }
    }
}