MirrorHub/nixpkgs
0
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-11-16 23:03:40 +01:00
Code Issues Projects Releases Packages Wiki Activity Actions 2

uwsm: init at 0.17.0

Browse source
This commit is contained in:
John Titor 2024-07-24 10:42:57 +05:30
parent c767888e06
commit 1bbd88fb35
No known key found for this signature in database
GPG key ID: 29B0514F4E3C1CC0
1 changed files with 71 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

71
pkgs/by-name/uw/uwsm/package.nix Normal file
View file

@ -0,0 +1,71 @@
{
stdenv,
lib,
fetchFromGitHub,
meson,
ninja,
scdoc,
pkg-config,
nix-update-script,
dmenu,
libnotify,
python3Packages,
util-linux,
fumonSupport ? true,
uuctlSupport ? true,
uwsmAppSupport ? true,
}:
let
python = python3Packages.python.withPackages (ps: [
ps.pydbus
ps.dbus-python
ps.pyxdg
]);
in
stdenv.mkDerivation (finalAttrs: {
pname = "uwsm";
version = "0.17.0";
src = fetchFromGitHub {
owner = "Vladimir-csp";
repo = "uwsm";
rev = "refs/tags/v${finalAttrs.version}";
hash = "sha256-M2j7l5XTSS2IzaJofAHct1tuAO2A9Ps9mCgAWKEvzoE=";
};
nativeBuildInputs = [
meson
ninja
pkg-config
scdoc
];
buildInputs = [
libnotify
util-linux
] ++ (lib.optionals uuctlSupport [ dmenu ]);
propagatedBuildInputs = [ python ];
mesonFlags = [
"--prefix=${placeholder "out"}"
(lib.mapAttrsToList lib.mesonEnable {
"uwsm-app" = uwsmAppSupport;
"fumon" = fumonSupport;
"uuctl" = uuctlSupport;
"man-pages" = true;
})
];
passthru = {
updateScript = nix-update-script { };
};
meta = {
description = "Universal wayland session manager";
homepage = "https://github.com/Vladimir-csp/uwsm";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ johnrtitor ];
platforms = lib.platforms.linux;
};
})