From 1bfe78be717728d9ff185e805a37454bd9d95956 Mon Sep 17 00:00:00 2001
From: Tobias Geerinckx-Rice <tobias.geerinckx.rice@gmail.com>
Date: Tue, 26 Jan 2016 00:49:50 +0100
Subject: [PATCH] bashburn: init at 3.1.0

---
 pkgs/tools/cd-dvd/bashburn/default.nix | 64 ++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix        |  2 +
 2 files changed, 66 insertions(+)
 create mode 100644 pkgs/tools/cd-dvd/bashburn/default.nix

diff --git a/pkgs/tools/cd-dvd/bashburn/default.nix b/pkgs/tools/cd-dvd/bashburn/default.nix
new file mode 100644
index 000000000000..b188b6fb2b2a
--- /dev/null
+++ b/pkgs/tools/cd-dvd/bashburn/default.nix
@@ -0,0 +1,64 @@
+{ stdenv, fetchurl, utillinux
+, cdparanoia, cdrdao, dvdplusrwtools, flac, lame, mpg123, normalize
+, vorbisTools, xorriso }:
+
+stdenv.mkDerivation rec {
+  name = "bashburn-${version}";
+  version = "3.1.0";
+
+  src = fetchurl {
+    sha256 = "0g5va5rjdrvacanmqr6pbxk2rl565ahkfbsvxsp1jvhvxvhmv3dp";
+    url = "http://bashburn.dose.se/index.php?s=file_download&id=25";
+    name = "${name}.tar.gz";
+  };
+
+  nativeBuildInputs = [ utillinux ];
+
+  postPatch = ''
+    for path in \
+      BB_CDBURNCMD=${xorriso}/bin/"xorriso -as cdrecord" \
+      BB_DVDBURNCMD=${dvdplusrwtools}/bin/growisofs \
+      BB_ISOCMD=${xorriso}/bin/"xorriso -as mkisofs" \
+      BB_DVDBLANK=${dvdplusrwtools}/bin/dvd+rw-format \
+      BB_CDIMAGECMD=${cdrdao}/bin/cdrdao \
+      BB_CDAUDIORIP=${cdparanoia}/bin/cdparanoia \
+      BB_READCD=${xorriso}/bin/"xorriso -as mkisofs" \
+      BB_MP3ENC=${lame}/bin/lame \
+      BB_MP3DEC=${mpg123}/bin/mpg123 \
+      BB_OGGENC=${vorbisTools}/bin/oggenc \
+      BB_OGGDEC=${vorbisTools}/bin/oggdec \
+      BB_FLACCMD=${flac}/bin/flac \
+      BB_EJECT=${utillinux}/bin/eject \
+      BB_NORMCMD=${normalize}/bin/normalize \
+    ; do
+      echo $path
+      sed -i BashBurn.sh \
+        -e "s,\(''${path%%=*}:\).*,\1 ''${path#*=},"
+      sed -i menus/advanced.sh \
+        -e "s,\(''${path%%=*}|\).*\('.*\),\1''${path#*=}\2,"
+    done
+  '';
+
+  installPhase = ''
+    sh Install.sh --prefix $out
+  '';
+
+  meta = with stdenv.lib; {
+    description = "bash script CD Burner Writer";
+    longDescription = ''
+      It might not be the best looking application out there, but it works.
+      It’s simple, fast and small, and can handle most things you throw at it.
+      Currently (and with the right dependencies installed), BashBurn can:
+      - burn data CDs/DVDs (Including CDRWs)
+      - burn music CDs
+      - burn CD/DVD-images
+      - rip data/music CDs
+      - manipulate ISO-files
+      - and probably more...
+    '';
+    homepage = http://bashburn.dose.se/;
+    license = licenses.gpl2Plus;
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ nckx ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index c63448f4a3a2..59c86b25a004 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -675,6 +675,8 @@ let
 
   barcode = callPackage ../tools/graphics/barcode {};
 
+  bashburn = callPackage ../tools/cd-dvd/bashburn { };
+
   bashmount = callPackage ../tools/filesystems/bashmount {};
 
   bc = callPackage ../tools/misc/bc { };