From 74cc92f93b51170af8fa4a34734d1d5a851c1848 Mon Sep 17 00:00:00 2001
From: Anderson Torres <torres.anderson.85@protonmail.com>
Date: Wed, 1 Feb 2023 06:18:01 -0300
Subject: [PATCH] rpcemu: init at 0.9.4

---
 .../applications/emulators/rpcemu/default.nix | 65 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 67 insertions(+)
 create mode 100644 pkgs/applications/emulators/rpcemu/default.nix

diff --git a/pkgs/applications/emulators/rpcemu/default.nix b/pkgs/applications/emulators/rpcemu/default.nix
new file mode 100644
index 000000000000..9befb172fe4b
--- /dev/null
+++ b/pkgs/applications/emulators/rpcemu/default.nix
@@ -0,0 +1,65 @@
+{ lib
+, stdenv
+, fetchhg
+, qt5
+}:
+
+let
+  inherit (qt5) qtbase qtmultimedia wrapQtAppsHook;
+in
+stdenv.mkDerivation (self: {
+  pname = "rpcemu";
+  version = "0.9.4";
+
+  src = fetchhg {
+    url = "http://www.home.marutan.net/hg/rpcemu";
+    rev = "release_${self.version}";
+    sha256 = "sha256-UyjfTfUpSvJNFPkQWPKppxp/kO0hVGo5cE9RuCU8GJI=";
+  };
+
+  nativeBuildInputs = [
+    wrapQtAppsHook
+  ];
+
+  buildInputs = [
+    qtbase
+    qtmultimedia
+  ];
+
+  configurePhase = ''
+    runHook preConfigure
+
+    cd src/qt5
+    qmake
+
+    runHook postConfigure
+  '';
+
+  installPhase = ''
+    runHook preInstall
+
+    cd ../..
+    install -Dm755 rpcemu-interpreter -t $out/bin
+
+    runHook postInstall
+  '';
+
+  meta = {
+    homepage = "https://www.marutan.net/rpcemu/index.php";
+    description = "Risc PC Emulator";
+    longDescription = ''
+      RPCEmu is an emulator of classic Acorn computer systems, such as the Risc
+      PC and A7000. It runs on multiple platforms including Windows, Linux and
+      Mac OS X.
+
+      RPCEmu should be considered Alpha Quality code. It has many known and
+      unknown bugs, and all files used with it should be well backed up before
+      using them with RPCEmu.
+    '';
+    license = lib.licenses.gpl2Plus;
+    maintainers =  builtins.attrValues {
+      inherit (lib.maintainers) AndersonTorres;
+    };
+    platforms = lib.platforms.linux;
+  };
+})
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index cd0415aa89f0..3a8a8a0342f9 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2164,6 +2164,8 @@ with pkgs;
 
   ripes = libsForQt5.callPackage ../applications/emulators/ripes { };
 
+  rpcemu = callPackage ../applications/emulators/rpcemu { };
+
   rpcs3 = libsForQt5.callPackage ../applications/emulators/rpcs3 { };
 
   ruffle = callPackage ../applications/emulators/ruffle { };