MirrorHub/nixpkgs
0
0
Fork 0
mirror of https://github.com/NixOS/nixpkgs.git synced 2024-11-16 23:03:40 +01:00
Code Issues Projects Releases Packages Wiki Activity Actions 1

aribb25: init at 0.2.7 (#96553)

Browse source 
* aribb25: init at 0.2.7

* fixup! aribb25: init at 0.2.7
This commit is contained in:
midchildan 2020-10-04 17:12:40 +09:00 committed by GitHub
parent 0dbce97034
commit 8129b1d754
No known key found for this signature in database
GPG key ID: 4AEE18F83AFDEB23
2 changed files with 61 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

57
pkgs/development/libraries/aribb25/default.nix Normal file
View file

@ -0,0 +1,57 @@
{ stdenv
, lib
, fetchFromGitLab
, fetchpatch
, autoreconfHook
, pkgconfig
, pcsclite
, PCSC
, xcbuild
}:
stdenv.mkDerivation rec {
pname = "aribb25";
# FIXME: change the rev for fetchFromGitLab in next release
version = "0.2.7";
src = fetchFromGitLab {
domain = "code.videolan.org";
owner = "videolan";
repo = pname;
# rev = version; FIXME: uncomment in next release
rev = "c14938692b313b5ba953543fd94fd1cad0eeef18"; # 0.2.7 with build fixes
sha256 = "1kb9crfqib0npiyjk4zb63zqlzbhqm35nz8nafsvdjd71qbd2amp";
};
nativeBuildInputs = [
autoreconfHook
pkgconfig
] ++ lib.optional stdenv.isDarwin xcbuild;
buildInputs = if stdenv.isDarwin then [ PCSC ] else [ pcsclite ];
patches = let
url = commit: "https://code.videolan.org/videolan/${pname}/-/commit/${commit}.diff";
in [
(fetchpatch {
name = "make-cli-pipes-work-1.patch";
url = url "0425184dbf3fdaf59854af5f530da88b2196a57b";
sha256 = "0ysm2jivpnqxz71vw1102616qxww2gx005i0c5lhi6jbajqsa1cd";
})
(fetchpatch {
name = "make-cli-pipes-work-2.patch";
url = url "cebabeab2bda065dca1c9f033b42d391be866d86";
sha256 = "1283kqv1r4rbaba0sv2hphkhcxgjkmh8ndlcd24fhx43nn63hd28";
})
];
buildFlags =
lib.optional stdenv.isDarwin "pcsclite_CFLAGS=-I${PCSC}/Library/Frameworks/PCSC.framework/Headers";
meta = with stdenv.lib; {
homepage = "https://code.videolan.org/videolan/aribb25";
description = "Sample implementation of the ARIB STD-B25 standard";
platforms = platforms.all;
license = licenses.isc;
maintainers = with maintainers; [ midchildan ];
};
}

4
pkgs/top-level/all-packages.nix
View file

@ -11878,6 +11878,10 @@ in
argp-standalone = callPackage ../development/libraries/argp-standalone {};
aribb25 = callPackage ../development/libraries/aribb25 {
inherit (darwin.apple_sdk.frameworks) PCSC;
};
armadillo = callPackage ../development/libraries/armadillo {};
arrayfire = callPackage ../development/libraries/arrayfire {};