mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-16 23:03:40 +01:00
05aa80c06a
Due the recent inclusion of broadcom-bt-firmware in enableAllFirmware, it was required to set `nixpkgs.config.allowUnfree` to obtain the full list. To make this dependency more explicit an assertion is added and an alternative option `enableRedistributalFirmware` is provided to only obtain firmware with an license allowing redistribution.
58 lines
1.4 KiB
Nix
58 lines
1.4 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.hardware;
|
|
in {
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
hardware.enableAllFirmware = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Turn on this option if you want to enable all the firmware.
|
|
'';
|
|
};
|
|
|
|
hardware.enableRedistributalFirmware = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = ''
|
|
Turn on this option if you want to enable all the firmware with a license allowing redistribution.
|
|
(i.e. free firmware and <literal>firmware-linux-nonfree</literal>)
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkMerge [
|
|
(mkIf (cfg.enableAllFirmware || cfg.enableRedistributalFirmware) {
|
|
hardware.firmware = with pkgs; [
|
|
firmwareLinuxNonfree
|
|
intel2200BGFirmware
|
|
rtl8723bs-firmware
|
|
rtl8192su-firmware
|
|
];
|
|
})
|
|
(mkIf cfg.enableAllFirmware {
|
|
assertions = [{
|
|
assertion = !cfg.enableAllFirmware || (config.nixpkgs.config.allowUnfree or false);
|
|
message = ''
|
|
the list of hardware.enableAllFirmware contains non-redistributable licensed firmware files.
|
|
This requires nixpkgs.config.allowUnfree to be true.
|
|
An alternative is to use the hardware.enableRedistributalFirmware option.
|
|
'';
|
|
}];
|
|
hardware.firmware = with pkgs; [
|
|
broadcom-bt-firmware
|
|
];
|
|
})
|
|
];
|
|
}
|