mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-16 14:54:29 +01:00
fc614c37c6
most modules can be evaluated for their documentation in a very restricted environment that doesn't include all of nixpkgs. this evaluation can then be cached and reused for subsequent builds, merging only documentation that has changed into the cached set. since nixos ships with a large number of modules of which only a few are used in any given config this can save evaluation a huge percentage of nixos options available in any given config. in tests of this caching, despite having to copy most of nixos/, saves about 80% of the time needed to build the system manual, or about two second on the machine used for testing. build time for a full system config shrank from 9.4s to 7.4s, while turning documentation off entirely shortened the build to 7.1s.
53 lines
1.4 KiB
Nix
53 lines
1.4 KiB
Nix
{ libPath
|
|
, pkgsLibPath
|
|
, nixosPath
|
|
, modules
|
|
, stateVersion
|
|
, release
|
|
}:
|
|
|
|
let
|
|
lib = import libPath;
|
|
modulesPath = "${nixosPath}/modules";
|
|
# dummy pkgs set that contains no packages, only `pkgs.lib` from the full set.
|
|
# not having `pkgs.lib` causes all users of `pkgs.formats` to fail.
|
|
pkgs = import pkgsLibPath {
|
|
inherit lib;
|
|
pkgs = null;
|
|
};
|
|
utils = import "${nixosPath}/lib/utils.nix" {
|
|
inherit config lib;
|
|
pkgs = null;
|
|
};
|
|
# this is used both as a module and as specialArgs.
|
|
# as a module it sets the _module special values, as specialArgs it makes `config`
|
|
# unusable. this causes documentation attributes depending on `config` to fail.
|
|
config = {
|
|
_module.check = false;
|
|
_module.args = {};
|
|
system.stateVersion = stateVersion;
|
|
};
|
|
eval = lib.evalModules {
|
|
modules = (map (m: "${modulesPath}/${m}") modules) ++ [
|
|
config
|
|
];
|
|
specialArgs = {
|
|
inherit config pkgs utils;
|
|
};
|
|
};
|
|
docs = import "${nixosPath}/doc/manual" {
|
|
pkgs = pkgs // {
|
|
inherit lib;
|
|
# duplicate of the declaration in all-packages.nix
|
|
buildPackages.nixosOptionsDoc = attrs:
|
|
(import "${nixosPath}/lib/make-options-doc")
|
|
({ inherit pkgs lib; } // attrs);
|
|
};
|
|
config = config.config;
|
|
options = eval.options;
|
|
version = release;
|
|
revision = "release-${release}";
|
|
prefix = modulesPath;
|
|
};
|
|
in
|
|
docs.optionsNix
|