mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-15 22:36:23 +01:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
64 lines
1.6 KiB
Nix
64 lines
1.6 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.gobgpd;
|
|
format = pkgs.formats.toml { };
|
|
confFile = format.generate "gobgpd.conf" cfg.settings;
|
|
in {
|
|
options.services.gobgpd = {
|
|
enable = mkEnableOption "GoBGP Routing Daemon";
|
|
|
|
settings = mkOption {
|
|
type = format.type;
|
|
default = { };
|
|
description = ''
|
|
GoBGP configuration. Refer to
|
|
<https://github.com/osrg/gobgp#documentation>
|
|
for details on supported values.
|
|
'';
|
|
example = literalExpression ''
|
|
{
|
|
global = {
|
|
config = {
|
|
as = 64512;
|
|
router-id = "192.168.255.1";
|
|
};
|
|
};
|
|
neighbors = [
|
|
{
|
|
config = {
|
|
neighbor-address = "10.0.255.1";
|
|
peer-as = 65001;
|
|
};
|
|
}
|
|
{
|
|
config = {
|
|
neighbor-address = "10.0.255.2";
|
|
peer-as = 65002;
|
|
};
|
|
}
|
|
];
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
environment.systemPackages = [ pkgs.gobgpd ];
|
|
systemd.services.gobgpd = {
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
description = "GoBGP Routing Daemon";
|
|
serviceConfig = {
|
|
Type = "notify";
|
|
ExecStartPre = "${pkgs.gobgpd}/bin/gobgpd -f ${confFile} -d";
|
|
ExecStart = "${pkgs.gobgpd}/bin/gobgpd -f ${confFile} --sdnotify";
|
|
ExecReload = "${pkgs.gobgpd}/bin/gobgpd -r";
|
|
DynamicUser = true;
|
|
AmbientCapabilities = "cap_net_bind_service";
|
|
};
|
|
};
|
|
};
|
|
}
|