mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-15 14:26:33 +01:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
61 lines
1.7 KiB
Nix
61 lines
1.7 KiB
Nix
{ pkgs, lib, config, ... }:
|
|
let
|
|
cfg = config.programs.nix-ld;
|
|
|
|
nix-ld-libraries = pkgs.buildEnv {
|
|
name = "ld-library-path";
|
|
pathsToLink = [ "/lib" ];
|
|
paths = map lib.getLib cfg.libraries;
|
|
# TODO make glibc here configurable?
|
|
postBuild = ''
|
|
ln -s ${pkgs.stdenv.cc.bintools.dynamicLinker} $out/share/nix-ld/lib/ld.so
|
|
'';
|
|
extraPrefix = "/share/nix-ld";
|
|
ignoreCollisions = true;
|
|
};
|
|
in
|
|
{
|
|
meta.maintainers = [ lib.maintainers.mic92 ];
|
|
options.programs.nix-ld = {
|
|
enable = lib.mkEnableOption ''nix-ld, Documentation: <https://github.com/Mic92/nix-ld>'';
|
|
package = lib.mkPackageOption pkgs "nix-ld" { };
|
|
libraries = lib.mkOption {
|
|
type = lib.types.listOf lib.types.package;
|
|
description = "Libraries that automatically become available to all programs. The default set includes common libraries.";
|
|
default = [ ];
|
|
defaultText = lib.literalExpression "baseLibraries derived from systemd and nix dependencies.";
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf config.programs.nix-ld.enable {
|
|
environment.ldso = "${cfg.package}/libexec/nix-ld";
|
|
|
|
environment.systemPackages = [ nix-ld-libraries ];
|
|
|
|
environment.pathsToLink = [ "/share/nix-ld" ];
|
|
|
|
environment.variables = {
|
|
NIX_LD = "/run/current-system/sw/share/nix-ld/lib/ld.so";
|
|
NIX_LD_LIBRARY_PATH = "/run/current-system/sw/share/nix-ld/lib";
|
|
};
|
|
|
|
# We currently take all libraries from systemd and nix as the default.
|
|
# Is there a better list?
|
|
programs.nix-ld.libraries = with pkgs; [
|
|
zlib
|
|
zstd
|
|
stdenv.cc.cc
|
|
curl
|
|
openssl
|
|
attr
|
|
libssh
|
|
bzip2
|
|
libxml2
|
|
acl
|
|
libsodium
|
|
util-linux
|
|
xz
|
|
systemd
|
|
];
|
|
};
|
|
}
|