mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-16 14:54:29 +01:00
dbf2b9152f
This will package up the closure of pkgs.hello in a tarball, and will later on verify machinectl pull-tar properly unpacked it, serving as a regression test for #108158. Closes #108158
71 lines
2.1 KiB
Nix
71 lines
2.1 KiB
Nix
import ./make-test-python.nix ({pkgs, lib, ...}:
|
|
let
|
|
gpgKeyring = (pkgs.runCommand "gpg-keyring" { buildInputs = [ pkgs.gnupg ]; } ''
|
|
mkdir -p $out
|
|
export GNUPGHOME=$out
|
|
cat > foo <<EOF
|
|
%echo Generating a basic OpenPGP key
|
|
%no-protection
|
|
Key-Type: DSA
|
|
Key-Length: 1024
|
|
Subkey-Type: ELG-E
|
|
Subkey-Length: 1024
|
|
Name-Real: Joe Tester
|
|
Name-Email: joe@foo.bar
|
|
Expire-Date: 0
|
|
# Do a commit here, so that we can later print "done"
|
|
%commit
|
|
%echo done
|
|
EOF
|
|
gpg --batch --generate-key foo
|
|
rm $out/S.gpg-agent $out/S.gpg-agent.*
|
|
gpg --export joe@foo.bar -a > $out/pubkey.gpg
|
|
'');
|
|
|
|
nspawnImages = (pkgs.runCommand "localhost" { buildInputs = [ pkgs.coreutils pkgs.gnupg ]; } ''
|
|
mkdir -p $out
|
|
cd $out
|
|
|
|
# produce a testimage.raw
|
|
dd if=/dev/urandom of=$out/testimage.raw bs=$((1024*1024+7)) count=5
|
|
|
|
# produce a testimage2.tar.xz, containing the hello store path
|
|
tar cvJpf testimage2.tar.xz ${pkgs.hello}
|
|
|
|
# produce signature(s)
|
|
sha256sum testimage* > SHA256SUMS
|
|
export GNUPGHOME="$(mktemp -d)"
|
|
cp -R ${gpgKeyring}/* $GNUPGHOME
|
|
gpg --batch --sign --detach-sign --output SHA256SUMS.gpg SHA256SUMS
|
|
'');
|
|
in {
|
|
name = "systemd-nspawn";
|
|
|
|
nodes = {
|
|
server = { pkgs, ... }: {
|
|
networking.firewall.allowedTCPPorts = [ 80 ];
|
|
services.nginx = {
|
|
enable = true;
|
|
virtualHosts."server".root = nspawnImages;
|
|
};
|
|
};
|
|
client = { pkgs, ... }: {
|
|
environment.etc."systemd/import-pubring.gpg".source = "${gpgKeyring}/pubkey.gpg";
|
|
};
|
|
};
|
|
|
|
testScript = ''
|
|
start_all()
|
|
|
|
server.wait_for_unit("nginx.service")
|
|
client.wait_for_unit("network-online.target")
|
|
client.succeed("machinectl pull-raw --verify=signature http://server/testimage.raw")
|
|
client.succeed(
|
|
"cmp /var/lib/machines/testimage.raw ${nspawnImages}/testimage.raw"
|
|
)
|
|
client.succeed("machinectl pull-tar --verify=signature http://server/testimage2.tar.xz")
|
|
client.succeed(
|
|
"cmp /var/lib/machines/testimage2/${pkgs.hello}/bin/hello ${pkgs.hello}/bin/hello"
|
|
)
|
|
'';
|
|
})
|