mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-15 14:26:33 +01:00
6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
66 lines
1.9 KiB
Nix
66 lines
1.9 KiB
Nix
{ config, pkgs, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.corectrl;
|
|
in
|
|
{
|
|
options.programs.corectrl = {
|
|
enable = mkEnableOption ''
|
|
CoreCtrl, a tool to overclock amd graphics cards and processors.
|
|
Add your user to the corectrl group to run corectrl without needing to enter your password
|
|
'';
|
|
|
|
package = mkPackageOption pkgs "corectrl" {
|
|
extraDescription = "Useful for overriding the configuration options used for the package.";
|
|
};
|
|
|
|
gpuOverclock = {
|
|
enable = mkEnableOption ''
|
|
GPU overclocking
|
|
'';
|
|
ppfeaturemask = mkOption {
|
|
type = types.str;
|
|
default = "0xfffd7fff";
|
|
example = "0xffffffff";
|
|
description = ''
|
|
Sets the `amdgpu.ppfeaturemask` kernel option.
|
|
In particular, it is used here to set the overdrive bit.
|
|
Default is `0xfffd7fff` as it is less likely to cause flicker issues.
|
|
Setting it to `0xffffffff` enables all features.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable (lib.mkMerge [
|
|
{
|
|
environment.systemPackages = [ cfg.package ];
|
|
|
|
services.dbus.packages = [ cfg.package ];
|
|
|
|
users.groups.corectrl = { };
|
|
|
|
security.polkit.extraConfig = ''
|
|
polkit.addRule(function(action, subject) {
|
|
if ((action.id == "org.corectrl.helper.init" ||
|
|
action.id == "org.corectrl.helperkiller.init") &&
|
|
subject.local == true &&
|
|
subject.active == true &&
|
|
subject.isInGroup("corectrl")) {
|
|
return polkit.Result.YES;
|
|
}
|
|
});
|
|
'';
|
|
}
|
|
|
|
(lib.mkIf cfg.gpuOverclock.enable {
|
|
# https://git.kernel.org/pub/scm/linux/kernel/git/torvalds/linux.git/tree/drivers/gpu/drm/amd/include/amd_shared.h#n169
|
|
# The overdrive bit
|
|
boot.kernelParams = [ "amdgpu.ppfeaturemask=${cfg.gpuOverclock.ppfeaturemask}" ];
|
|
})
|
|
]);
|
|
|
|
meta.maintainers = with lib.maintainers; [ artturin ];
|
|
}
|