mirror of
https://github.com/NixOS/nixpkgs.git
synced 2024-11-15 06:14:57 +01:00
5dfdb09561
While preparing this change, I read the git blame on all of the files I touched. I saw a working lifetime of building this system which we use every day and love dearly and keep maintained ourselves. I saw commits from a 14 year range between 2003 to 2017!! I could not be more thankful for Eelco's work on building large parts of the foundation of nixpkgs that all of us rely on now. However, the end date of that range of the files I looked at the blame on was 2017. I did not see surviving code from any newer date than that. Looking at the Git logs, Eelco has been working on other things, and that's totally fine. However, it means that our maintenance metadata is out of date on a lot of packages, and *that*'s the reason I am submitting this change. There are a lot of packages that don't have anyone with their name on them to be pinged if they need attention, even if they have had recent activity (although it is never clear if recent activity was just someone fixing it because ZHF or because the package actually matters to them). There are a lot of packages with storied history that maybe don't need to be in the set anymore at all since they have not been touched in years; or maybe they are simply finished. Empty maintainer lists should be a sign that we need to figure out who maintains it or potentially remove it if it has rotted, and allowing the maintainer list to be empty if it is already not maintained is part of a healthy repository ecology. Either way, I would like to have the maintenance metadata not mislead anyone into sending Eelco emails about packages he doesn't, in practice, work on anymore. I have not removed his name from everything; there are some things that he is the upstream for or has worked on more recently, for instance, like Nix, which I have left alone.
88 lines
2.6 KiB
Nix
88 lines
2.6 KiB
Nix
{ config, lib, stdenv, fetchFromGitHub, cmake, pkg-config, xorg, libGLU
|
|
, libGL, glew, ocl-icd, python3
|
|
, cudaSupport ? config.cudaSupport
|
|
, cudaPackages
|
|
, openclSupport ? !cudaSupport
|
|
, darwin
|
|
}:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "opensubdiv";
|
|
version = "3.6.0";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "PixarAnimationStudios";
|
|
repo = "OpenSubdiv";
|
|
rev = "v${lib.replaceStrings ["."] ["_"] version}";
|
|
sha256 = "sha256-liy6pQyWMk7rw0usrCoLGzZLO7RAg0z2pV/GF2NnOkE=";
|
|
};
|
|
|
|
outputs = [ "out" "dev" "static" ];
|
|
|
|
nativeBuildInputs = [
|
|
cmake
|
|
pkg-config
|
|
] ++ lib.optional cudaSupport [
|
|
cudaPackages.cuda_nvcc
|
|
];
|
|
buildInputs =
|
|
[ libGLU libGL python3
|
|
# FIXME: these are not actually needed, but the configure script wants them.
|
|
glew xorg.libX11 xorg.libXrandr xorg.libXxf86vm xorg.libXcursor
|
|
xorg.libXinerama xorg.libXi
|
|
]
|
|
++ lib.optionals (openclSupport && !stdenv.isDarwin) [ ocl-icd ]
|
|
++ lib.optionals stdenv.isDarwin (with darwin.apple_sdk.frameworks; [
|
|
OpenCL
|
|
Cocoa
|
|
CoreVideo
|
|
IOKit
|
|
AppKit
|
|
AGL
|
|
MetalKit
|
|
])
|
|
++ lib.optionals cudaSupport [
|
|
cudaPackages.cuda_cudart
|
|
];
|
|
|
|
# It's important to set OSD_CUDA_NVCC_FLAGS,
|
|
# because otherwise OSD might piggyback unwanted architectures:
|
|
# https://github.com/PixarAnimationStudios/OpenSubdiv/blob/7d0ab5530feef693ac0a920585b5c663b80773b3/CMakeLists.txt#L602
|
|
preConfigure = lib.optionalString cudaSupport ''
|
|
cmakeFlagsArray+=(
|
|
-DOSD_CUDA_NVCC_FLAGS="${lib.concatStringsSep " " cudaPackages.cudaFlags.gencode}"
|
|
)
|
|
'';
|
|
|
|
cmakeFlags =
|
|
[ "-DNO_TUTORIALS=1"
|
|
"-DNO_REGRESSION=1"
|
|
"-DNO_EXAMPLES=1"
|
|
(lib.cmakeBool "NO_METAL" (!stdenv.isDarwin))
|
|
(lib.cmakeBool "NO_OPENCL" (!openclSupport))
|
|
(lib.cmakeBool "NO_CUDA" (!cudaSupport))
|
|
] ++ lib.optionals (!stdenv.isDarwin) [
|
|
"-DGLEW_INCLUDE_DIR=${glew.dev}/include"
|
|
"-DGLEW_LIBRARY=${glew.dev}/lib"
|
|
] ++ lib.optionals cudaSupport [
|
|
] ++ lib.optionals (!openclSupport) [
|
|
];
|
|
|
|
preBuild = let maxBuildCores = 16; in lib.optionalString cudaSupport ''
|
|
# https://github.com/PixarAnimationStudios/OpenSubdiv/issues/1313
|
|
NIX_BUILD_CORES=$(( NIX_BUILD_CORES < ${toString maxBuildCores} ? NIX_BUILD_CORES : ${toString maxBuildCores} ))
|
|
'';
|
|
|
|
postInstall = ''
|
|
moveToOutput "lib/*.a" $static
|
|
'';
|
|
|
|
meta = {
|
|
description = "Open-Source subdivision surface library";
|
|
homepage = "http://graphics.pixar.com/opensubdiv";
|
|
broken = openclSupport && cudaSupport;
|
|
platforms = lib.platforms.unix;
|
|
maintainers = [ ];
|
|
license = lib.licenses.asl20;
|
|
};
|
|
}
|