.SRCINFO

@@ -0,0 +1,26 @@
+pkgbase = precice-git
+	pkgdesc = A Coupling Library for Partitioned Multi-Physics Simulations on Massively Parallel Systems (git version)
+	pkgver = 2.5.0.r7.gb8a1fed8
+	pkgrel = 2
+	url = https://precice.org
+	arch = x86_64
+	license = LGPL3
+	checkdepends = openssh
+	makedepends = cmake
+	makedepends = gcc-fortran
+	makedepends = doxygen
+	makedepends = graphviz
+	makedepends = git
+	makedepends = texlive-core
+	depends = libxml2
+	depends = petsc
+	depends = eigen
+	depends = jsoncpp
+	optdepends = man-db: manual pages for precice-tools and testprecice
+	optdepends = git: for Git Revision Info support
+	provides = precice
+	conflicts = precice
+	source = git+https://github.com/precice/precice.git#branch=develop
+	sha512sums = SKIP
+
+pkgname = precice-git

.gitignore

@@ -0,0 +1 @@
+*

PKGBUILD

@@ -0,0 +1,65 @@
+# Maintainer: Gerasimos Chourdakis <chourdak at in dot tum dot de>
+# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
+# Contributor: Florian Lindner <florian.lindner@xgm.de>
+_base=precice
+pkgname=${_base}-git
+pkgver=2.5.0.r7.gb8a1fed8
+pkgrel=2
+pkgdesc="A Coupling Library for Partitioned Multi-Physics Simulations on Massively Parallel Systems (git version)"
+arch=(x86_64)
+url="https://${_base}.org"
+license=(LGPL3)
+depends=(libxml2 petsc eigen jsoncpp)
+makedepends=(cmake gcc-fortran doxygen graphviz git texlive-core)
+checkdepends=(openssh)
+optdepends=('man-db: manual pages for precice-tools and testprecice'
+  'git: for Git Revision Info support')
+source=(git+https://github.com/${_base}/${_base}.git#branch=develop)
+sha512sums=('SKIP')
+provides=(${_base})
+conflicts=(${_base})
+
+pkgver() {
+  cd ${_base}
+  git describe --long --tags | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+  cmake \
+    -S ${_base} \
+    -B build \
+    -DCMAKE_BUILD_TYPE=None \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_CXX_STANDARD=17 \
+    -DPRECICE_MPICommunication=ON \
+    -DPRECICE_PETScMapping=ON \
+    -DPRECICE_PythonActions=ON \
+    -DBUILD_SHARED_LIBS=ON \
+    -DBUILD_TESTING=ON \
+    -DPRECICE_ALWAYS_VALIDATE_LIBS=ON \
+    -DPRECICE_ENABLE_C=ON \
+    -DPRECICE_ENABLE_FORTRAN=ON \
+    -DCMAKE_CXX_STANDARD_REQUIRED=Yes \
+    -DCMAKE_CXX_EXTENSIONS=No \
+    -DCMAKE_EXPORT_COMPILE_COMMANDS=ON \
+    -Wno-dev
+  cmake --build build --target all
+}
+
+check() {
+  if [ -z "$(ldconfig -p | grep libcuda.so.1)" ]; then
+    export OMPI_MCA_opal_warn_on_missing_libcuda=0
+  fi
+  ctest --test-dir build
+}
+
+package() {
+  DESTDIR="${pkgdir}" cmake --build build --target install doxygen
+  install -Dm 644 ${_base}/LICENSE -t ${pkgdir}/usr/share/licenses/${_base}
+  install -Dm 644 ${_base}/docs/man/man1/test${_base}.1 -t ${pkgdir}/usr/share/man/man1/
+  mv ${pkgdir}/usr/share/doc/lib${_base}2 ${pkgdir}/usr/share/doc/${_base}
+  install -d ${pkgdir}/usr/share/doc/${_base}
+  mv ${_base}/docs/source-code-documentation/html/* ${pkgdir}/usr/share/doc/${_base}
+  cd "${pkgdir}"
+  rm -r usr/share/lintian
+}

README.md

@@ -1,3 +0,0 @@
-# aur.git
-
-This is a experimental mirror of the aur.git repository backing [the AUR](https://aur.archlinux.org).