.SRCINFO

@@ -0,0 +1,32 @@
+pkgbase = coolero
+	pkgdesc = A program to monitor and control your cooling devices
+	pkgver = 0.12.7
+	pkgrel = 1
+	url = https://gitlab.com/coolero/coolero
+	arch = any
+	license = GPL3
+	checkdepends = appstream-glib
+	checkdepends = desktop-file-utils
+	makedepends = python-build
+	makedepends = python-installer
+	makedepends = python-poetry
+	depends = hicolor-icon-theme
+	depends = polkit
+	depends = python
+	depends = liquidctl
+	depends = pyside6
+	depends = qt6-svg
+	depends = python-apscheduler
+	depends = python-matplotlib
+	depends = python-numpy
+	depends = python-psutil
+	depends = python-setproctitle
+	depends = python-jeepney
+	depends = python-pyamdgpuinfo
+	optdepends = nvidia-utils: NVIDIA GPU support
+	provides = coolero
+	conflicts = coolero
+	source = https://gitlab.com/coolero/coolero/-/archive/0.12.7/coolero-0.12.7.tar.gz
+	sha256sums = 1b7a5be895c264510637c504e7384075b1a770d1cb4c4d5687540e1e3f257849
+
+pkgname = coolero

PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Guy Boldon <gb@guyboldon.com>
+
+pkgname=coolero
+_app_id="org.$pkgname.Coolero"
+pkgver=0.12.7
+pkgrel=1
+pkgdesc="A program to monitor and control your cooling devices"
+arch=('any')
+url="https://gitlab.com/coolero/coolero"
+license=('GPL3')
+depends=('hicolor-icon-theme' 'polkit' 'python' 'liquidctl' 'pyside6' 'qt6-svg' 'python-apscheduler'
+         'python-matplotlib' 'python-numpy' 'python-psutil' 'python-setproctitle' 'python-jeepney'
+         'python-pyamdgpuinfo')
+makedepends=('python-build' 'python-installer' 'python-poetry')
+checkdepends=('appstream-glib' 'desktop-file-utils')
+optdepends=('nvidia-utils: NVIDIA GPU support')
+provides=("$pkgname")
+conflicts=("$pkgname")
+source=("https://gitlab.com/coolero/coolero/-/archive/$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('1b7a5be895c264510637c504e7384075b1a770d1cb4c4d5687540e1e3f257849')
+
+build() {
+  cd "$pkgname-$pkgver"
+  python -m build --wheel --no-isolation
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  desktop-file-validate "metadata/$_app_id.desktop"
+  appstream-util validate-relax "metadata/$_app_id.metainfo.xml"
+  python -m coolero -v
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  python -m installer --destdir="$pkgdir" dist/*.whl
+
+  # systemd service files
+  install -Dm644 "packaging/systemd/${pkgname}d.service" -t "$pkgdir/usr/lib/systemd/system/"
+  install -Dm644 "packaging/systemd/${pkgname}d.socket" -t "$pkgdir/usr/lib/systemd/system/"
+  install -Dm644 "packaging/systemd/${pkgname}.conf" -t "$pkgdir/usr/lib/sysusers.d/"
+
+  # desktop metadata
+  install -Dm644 "metadata/$_app_id.desktop" -t "$pkgdir/usr/share/applications/"
+  install -Dm644 "metadata/$_app_id.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"
+  install -Dm644 "metadata/$_app_id.png" -t "$pkgdir/usr/share/pixmaps/"
+  install -Dm644 "metadata/$_app_id.svg" -t "$pkgdir/usr/share/icons/hicolor/scalable/apps/"
+}

README.md

@@ -1,3 +0,0 @@
-# aur.git
-
-This is a experimental mirror of the aur.git repository backing [the AUR](https://aur.archlinux.org).