/*
 * This file is part of Applied Energistics 2.
 * Copyright (c) 2013 - 2015, AlgorithmX2, All rights reserved.
 *
 * Applied Energistics 2 is free software: you can redistribute it and/or modify
 * it under the terms of the GNU Lesser General Public License as published by
 * the Free Software Foundation, either version 3 of the License, or
 * (at your option) any later version.
 *
 * Applied Energistics 2 is distributed in the hope that it will be useful,
 * but WITHOUT ANY WARRANTY; without even the implied warranty of
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 * GNU Lesser General Public License for more details.
 *
 * You should have received a copy of the GNU Lesser General Public License
 * along with Applied Energistics 2.  If not, see <http://www.gnu.org/licenses/lgpl>.
 */

buildscript {
    repositories {
        mavenLocal()
        jcenter()
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:2.2-SNAPSHOT'
    }
}
apply plugin: 'net.minecraftforge.gradle.forge'

repositories {
    mavenLocal()
    jcenter()
    mavenCentral()
}

dependencies {
    testCompile "junit:junit:4.12"
}

//apply from: 'gradle/scripts/dependencies.gradle'
apply from: 'gradle/scripts/artifacts.gradle'
//apply from: 'gradle/scripts/autoinstallruntime.gradle'
apply from: 'gradle/scripts/integration.gradle'
//apply from: 'gradle/scripts/optional.gradle'


sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

version = aeversion + "-" + aechannel + "-" + aebuild
group = aegroup
archivesBaseName = aebasename

// If TeamCity is running this build, lets set the version info
if (hasProperty("teamcity")) {
    version = teamcity["build.number"]

    // Fix for main branch being built
    version = version.replaceAll("/", "-")
}

// Add Coremod Manifest
jar {
    manifest {
        attributes 'FMLCorePluginContainsFMLMod': 'true'
    }

    // specify which files are really included, can control which APIs should be in
    include "appeng/**"
    include "assets/**"
    include "mcmod.info"
    include "pack.mcmeta"
}

minecraft {
    coreMod = "appeng.transformer.AppEngCore"

    version = minecraft_version + "-" + forge_version

    replaceIn "AEConfig.java"
    replaceIn "package-info.java"

    replace "@version@", project.version
    replace "@aeversion@", aeversion
    replace "@aechannel@", aechannel
    replace "@aebuild@", aebuild

    // used when launching minecraft in dev env
    runDir = "run"
    mappings = mcp_mappings
}

sourceSets {
    main {
        java {
            srcDirs += 'src/api/java'
            srcDirs += 'src/main/java/'
        }

        resources {
            srcDir "src/main/resources/"
            include "assets/appliedenergistics2/recipes/**/*.recipe",
                    "assets/appliedenergistics2/recipes/README.html",
                    "assets/appliedenergistics2/lang/*.lang",
                    "assets/appliedenergistics2/blockstates/**/*.json",
                    "assets/appliedenergistics2/models/**/*.json",
                    "assets/appliedenergistics2/textures/**/*.png",
                    "assets/appliedenergistics2/textures/**/*.mcmeta",
                    "assets/appliedenergistics2/meta/*",
                    "mcmod.info",
                    "pack.mcmeta"
        }
    }
}

processResources {
    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
        expand 'version': project.version, 'mcversion': minecraft_version
    }
}