Gradilisation, without moving everything around because that's annoying and makes merges difficult, and this way ant will still work as well.

`gradle :build` builds MekanismAll.jar (couldn't make it do separate ones on its own)
`gradle :releaseJars` generates MekanismCore, MekanismGenerators and MekanismTools.
It would be helpful if anyone has a maven repository of CB's mods...

.gitignore

@@ -1,3 +1,7 @@
+build
+src
+.gradle
+
 *.mtl
 *.blend1
 *.blend2

build.gradle

@@ -0,0 +1,96 @@
+buildscript {
+    repositories {
+        mavenCentral()
+        maven {
+            name = "forge"
+            url = "http://files.minecraftforge.net/maven"
+        }
+    }
+    dependencies {
+        classpath 'net.minecraftforge.gradle:ForgeGradle:1.0-SNAPSHOT'
+    }
+}
+
+apply plugin: 'forge'
+
+repositories {
+        flatDir name: 'localLibs', dirs: 'libs'
+}
+
+dependencies {
+        compile ':codechickenlib:1.0.0.49'
+        compile ':codechickencore:0.9.0.7'
+        compile ':nei:1.6.1.8'
+        compile ':forgemultipart:1.0.0.228'
+}
+
+version = "6.0.0"
+archivesBaseName = "MekanismAll"
+
+minecraft {
+	version = "1.6.4-9.11.1.964"
+}
+
+processResources
+{
+    dependsOn 'moveRes'
+
+    // replace stuff in mcmod.info, nothing else
+    from(sourceSets.main.resources.srcDirs) {
+        include 'mcmod/info'
+                
+        // replace version and mcversion
+        expand 'version':project.version, 'mcversion':project.minecraft.version
+    }
+        
+    // copy everything else, thats not the mcmod.info
+    from(sourceSets.main.resources.srcDirs) {
+        exclude 'mcmod.info'
+    }
+}
+
+task moveSrc(type: Sync) {
+    from 'common'
+    into 'src/main/java'
+}
+
+compileJava.dependsOn moveSrc
+
+task moveRes(type: Sync) {
+    from 'resources'
+    into 'src/main/resources'
+    exclude '**/*.blend*'
+}
+
+task coreJar(type: Jar) {
+    dependsOn 'reobf'
+    baseName = 'MekanismCore'
+    from 'etc/core'
+    from zipTree(reobf.outputs.getFiles().getSingleFile()).matching {
+        exclude 'mekanism/tools/**', 'mekanism/generators/**'
+    }
+}
+
+task toolsJar(type: Jar) {
+    dependsOn 'reobf'
+    baseName = 'MekanismTools'
+    from 'etc/tools'
+    from zipTree(reobf.outputs.getFiles().getSingleFile()).matching {
+        include 'mekanism/tools/**'
+    }
+}
+
+task generatorsJar(type: Jar) {
+    dependsOn 'reobf'
+    baseName = 'MekanismGenerators'
+    from 'etc/generators'
+    from zipTree(reobf.outputs.getFiles().getSingleFile()).matching {
+        include 'mekanism/generators/**'
+    }
+}
+
+task releaseJars {
+    dependsOn 'coreJar'
+    dependsOn 'toolsJar'
+    dependsOn 'generatorsJar'
+}