auracore/build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "https://maven.minecraftforge.net/"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath ('com.anatawa12.forge:ForgeGradle:1.2-1.0.+') {
            changing = true
        }
    }
}

apply plugin: 'forge'
apply plugin: 'maven-publish'
apply from: './gradle/scripts/mixins.gradle'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

version = "1.0.0"
group= "dev.tilera"
archivesBaseName = "auracore"

minecraft {
    version = "1.7.10-10.13.4.1614-1.7.10"
    runDir = "run"

    replaceIn "dev/tilera/auracore/AuraCore.java"
    replace "{VERSION}", project.version
}

repositories {
    maven { url = "https://maven.tilera.xyz" }
    maven { url = "https://jitpack.io" }
}

dependencies {
    implementation "thaumcraft:Thaumcraft:1.7.10-4.2.3.5:deobf"
    implementation "com.github.tox1cozZ:mixin-booter-legacy:1.1.2"
    annotationProcessor "com.github.tox1cozZ:mixin-booter-legacy:1.1.2:processor"
}

processResources {
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    filesMatching('mcmod.info') {
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
}

jar {
    manifest {
        attributes([
                "FMLCorePlugin"           : "dev.tilera.auracore.MixinLoader",
                "FMLCorePluginContainsFMLMod": "true"
        ])
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'deobf'
    manifest {
        attributes([
                "FMLCorePlugin"           : "dev.tilera.auracore.MixinLoader",
                "FMLCorePluginContainsFMLMod": "true"
        ])
    }
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

publishing {
    tasks.publish.dependsOn 'build'
    publications {
        mavenJava(MavenPublication) {
            artifactId = project.archivesBaseName

            artifact deobfJar
            artifact sourcesJar
            artifact jar
        }
    }

    repositories {
        if (project.hasProperty('mvnURL')) {
                maven {
                    credentials {
                        username findProperty("mvnUsername")
                        password findProperty("mvnPassword")
                    }
                    url = findProperty("mvnURL")
                }
        }
        else {
                mavenLocal()
        }
    }
}

mixin {
    mixinRefMapName = 'auracore.refmap.json'
}