classic-worldgen/build.gradle

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "https://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
        maven { url 'https://jitpack.io' }
    }
    dependencies {
        classpath 'com.github.GTNewHorizons:ForgeGradle:1.2.9'
    }
}

apply plugin: 'forge'
apply plugin: 'maven-publish'
apply from: './gradle/scripts/mixins.gradle'

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

version = "1.1.1"
group= "dev.tilera.modding"
archivesBaseName = "cwg"

minecraft {
    version = "1.7.10-10.13.4.1614-1.7.10"
    runDir = "run"
}


repositories {
    mavenCentral()
    maven {
        url = "https://maven.tilera.xyz"
    }
    maven { url 'https://jitpack.io' }
    maven {
        name 'Overmind forge repo mirror'
        url 'https://gregtech.overminddl1.com/'
    }
}

dependencies {
    compile "com.github.tox1cozZ:mixin-booter-legacy:1.1.2"
    annotationProcessor "com.github.tox1cozZ:mixin-booter-legacy:1.1.2:processor"
}

processResources
{
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
      
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

jar {
    manifest {
        attributes([
                "FMLCorePlugin"           : "dev.tilera.cwg.core.CWGCorePlugin",
                "FMLCorePluginContainsFMLMod": "true"
        ])
    }
}

sourceSets {
    main {
        java {
            srcDir 'src/main/java'
        }
        resources {
            srcDir 'src/main/resources'
        }
    }
}

task deobfJar(type: Jar) {
    from sourceSets.main.output
    classifier = 'deobf'
}

task sourcesJar(type: Jar) {
    from sourceSets.main.allSource
    classifier = 'sources'
}

publishing {
    tasks.publish.dependsOn 'build'
    publications {
        mavenJava(MavenPublication) {
            artifactId = project.archivesBaseName

            artifact deobfJar
            artifact sourcesJar
            artifact jar
        }
    }

    repositories {
        if (project.hasProperty('mvnURL')) {
                maven {
                    credentials {
                        username findProperty("mvnUsername")
                        password findProperty("mvnPassword")
                    }
                    url = findProperty("mvnURL")
                }
        }
        else {
                mavenLocal()
        }
    }
}

mixin {
    mixinRefMapName = 'cwg.refmap.json'
}