Since we clone the environments to build thirdparty code, we don't get an explicit dependency on the build objects produced by that environment. So when we update thirdparty code, Godot code using it is not necessarily rebuilt (I think it is for changed headers, but not for changed .c/.cpp files), which can lead to an invalid compilation output (linking old Godot .o files with a newer, potentially ABI breaking version of thirdparty code). This was only seen as really problematic with bullet updates (leading to crashes when rebuilding Godot after a bullet update without cleaning .o files), but it's safer to fix it everywhere, even if it's a LOT of hacky boilerplate.
59 lines
1.7 KiB
Python
59 lines
1.7 KiB
Python
#!/usr/bin/env python
|
|
|
|
Import("env")
|
|
Import("env_modules")
|
|
|
|
env_basisu = env_modules.Clone()
|
|
|
|
# Thirdparty source files
|
|
|
|
thirdparty_obj = []
|
|
|
|
# Not unbundled so far since not widespread as shared library
|
|
thirdparty_dir = "#thirdparty/basis_universal/"
|
|
tool_sources = [
|
|
"basisu_astc_decomp.cpp",
|
|
"basisu_backend.cpp",
|
|
"basisu_basis_file.cpp",
|
|
"basisu_comp.cpp",
|
|
"basisu_enc.cpp",
|
|
"basisu_etc.cpp",
|
|
"basisu_frontend.cpp",
|
|
"basisu_global_selector_palette_helpers.cpp",
|
|
"basisu_gpu_texture.cpp",
|
|
"basisu_pvrtc1_4.cpp",
|
|
"basisu_resample_filters.cpp",
|
|
"basisu_resampler.cpp",
|
|
"basisu_ssim.cpp",
|
|
"lodepng.cpp",
|
|
]
|
|
tool_sources = [thirdparty_dir + file for file in tool_sources]
|
|
transcoder_sources = [thirdparty_dir + "transcoder/basisu_transcoder.cpp"]
|
|
|
|
# Treat Basis headers as system headers to avoid raising warnings. Not supported on MSVC.
|
|
if not env.msvc:
|
|
env_basisu.Append(
|
|
CPPFLAGS=["-isystem", Dir(thirdparty_dir).path, "-isystem", Dir(thirdparty_dir + "transcoder").path]
|
|
)
|
|
else:
|
|
env_basisu.Prepend(CPPPATH=[thirdparty_dir, thirdparty_dir + "transcoder"])
|
|
|
|
if env["target"] == "debug":
|
|
env_basisu.Append(CPPFLAGS=["-DBASISU_DEVEL_MESSAGES=1", "-DBASISD_ENABLE_DEBUG_FLAGS=1"])
|
|
|
|
env_thirdparty = env_basisu.Clone()
|
|
env_thirdparty.disable_warnings()
|
|
if env["tools"]:
|
|
env_thirdparty.add_source_files(thirdparty_obj, tool_sources)
|
|
env_thirdparty.add_source_files(thirdparty_obj, transcoder_sources)
|
|
env.modules_sources += thirdparty_obj
|
|
|
|
# Godot source files
|
|
|
|
module_obj = []
|
|
|
|
env_basisu.add_source_files(module_obj, "*.cpp")
|
|
env.modules_sources += module_obj
|
|
|
|
# Needed to force rebuilding the module files when the thirdparty library is updated.
|
|
env.Depends(module_obj, thirdparty_obj)
|