ba2ec53a26
With the NDK installed locally, gradle plugin 3.6.0 seems to enforce a specific older NDK version, and will fail building if you don't have it installed with: ``` No version of NDK matched the requested version 20.0.5594570. Versions available locally: 21.0.6113669 ``` Upstream issue: https://github.com/gradle/gradle/issues/12440
67 lines
2.3 KiB
Groovy
67 lines
2.3 KiB
Groovy
ext.versions = [
|
|
androidGradlePlugin: '3.5.3',
|
|
compileSdk : 29,
|
|
minSdk : 18,
|
|
targetSdk : 29,
|
|
buildTools : '29.0.1',
|
|
supportCoreUtils : '28.0.0',
|
|
kotlinVersion : '1.3.61',
|
|
v4Support : '28.0.0'
|
|
|
|
]
|
|
|
|
ext.libraries = [
|
|
androidGradlePlugin: "com.android.tools.build:gradle:$versions.androidGradlePlugin",
|
|
supportCoreUtils : "com.android.support:support-core-utils:$versions.supportCoreUtils",
|
|
kotlinGradlePlugin : "org.jetbrains.kotlin:kotlin-gradle-plugin:$versions.kotlinVersion",
|
|
kotlinStdLib : "org.jetbrains.kotlin:kotlin-stdlib-jdk7:$versions.kotlinVersion",
|
|
v4Support : "com.android.support:support-v4:$versions.v4Support"
|
|
]
|
|
|
|
ext.getExportPackageName = { ->
|
|
// Retrieve the app id from the project property set by the Godot build command.
|
|
String appId = project.hasProperty("export_package_name") ? project.property("export_package_name") : ""
|
|
// Check if the app id is valid, otherwise use the default.
|
|
if (appId == null || appId.isEmpty()) {
|
|
appId = "com.godot.game"
|
|
}
|
|
return appId
|
|
}
|
|
|
|
/**
|
|
* Parse the project properties for the 'custom_template_plugins' property and return
|
|
* their binaries for inclusion in the build dependencies.
|
|
*
|
|
* The listed plugins must have their binaries in the project plugins directory.
|
|
*/
|
|
ext.getGodotPluginsBinaries = { ->
|
|
String[] binDeps = []
|
|
|
|
// Retrieve the list of enabled plugins.
|
|
if (project.hasProperty("custom_template_plugins")) {
|
|
String pluginsList = project.property("custom_template_plugins")
|
|
if (pluginsList != null && !pluginsList.trim().isEmpty()) {
|
|
for (String plugin : pluginsList.split(",")) {
|
|
binDeps += plugin.trim() + "*.aar"
|
|
}
|
|
}
|
|
}
|
|
|
|
return binDeps
|
|
}
|
|
|
|
/**
|
|
* Parse the project properties for the 'custom_template_plugins_dir' property and return
|
|
* its value.
|
|
*
|
|
* The returned value is the directory containing user plugins.
|
|
*/
|
|
ext.getGodotPluginsDirectory = { ->
|
|
// The plugins directory is provided by the 'custom_template_plugins_dir' property.
|
|
String pluginsDir = project.hasProperty("custom_template_plugins_dir")
|
|
? project.property("custom_template_plugins_dir")
|
|
: ""
|
|
|
|
return pluginsDir
|
|
}
|